À chaque parution d’une nouvelle mise à jour majeure de Windows 10, l’outil de création de support, indispensable pour télécharger le système d’exploitation, est également mis à niveau. Cette nouvelle mouture de l’outil permet d’obtenir la toute dernière version de Windows 10 disponible. Par conséquent, si vous désirez télécharger une version antérieure, l’outil proposé sur le site de Microsoft ne vous sera d’aucune utilité. Toutefois, les fichiers ISO des anciennes versions existent toujours et grâce à un petit script BAT, il est possible de télécharger n’importe quelle version de Windows 10 en utilisant l’outil de création de support.
AVIS : Un tutoriel vidéo est disponible à la fin de cet article, n’hésitez pas à le consulter.
Comment télécharger une version spécifique de Windows 10
Le fichier BAT que nous allons utiliser a été conçu par aveyo, un utilisateur de Reddit. Il est possible de le télécharger directement à partir de son lien Pastebin, mais nous allons également vous fournir le script ici, si jamais le lien venait à ne plus fonctionner.
Ouvrez le Bloc-notes et copiez-y le script ci-dessous. Enregistrez ensuite le fichier avec l’extension BAT.
@echo off &title MediaCreationTool.bat by AveYo
:: Wrapper universel pour toutes les versions "RedStone" : 1607, 1703, 1709, 1803 et 1809
:: Utilise uniquement les fichiers originaux hébergés par Microsoft pour les versions actuelles et passées du MCT de Windows 10
:: Prise en charge complète de la création de canaux professionnels (Entreprise) avec langue personnalisée, x86, x64 ou AIO !
:: Ajoutez / supprimez les paramètres de lancement ci-dessous si nécessaire - il est préréglé pour le moins de problèmes lors des mises à niveau
set "OPTIONS=/Telemetry Disable /DynamicUpdate Disable /MigrateDrivers all /ResizeRecoveryPartition disable /ShowOOBE none"
:: Décommentez pour afficher le journal de la console MCT en direct pour le débogage
rem set "OPTIONS=%OPTIONS% /Console"
:: Décommentez pour contourner la boîte de dialogue de choix de l'interface graphique et coder en dur la version cible: 1=1607, 2=1703, 3=1709, 4=1803, 5=1809
rem set/a MCT_VERSION=5
:: Versions MCT disponibles
set versions= 1607 [ RedStone 1 ], 1703 [ RedStone 2 ], 1709 [ RedStone 3 ], 1803 [ RedStone 4 ], 1809 [ RedStone 5 ]
:: Afficher la boîte de dialogue %1:title %2:header %3:choices %4:output_variable
if not defined MCT_VERSION call :choice "MediaCreationTool.bat by AveYo" "Choisissez la version de Windows 10" "%versions%" MCT_VERSION
if not defined MCT_VERSION echo Aucune MCT_VERSION sélectionnée, sortie.. & timeout /t 5 & exit/b
goto version%MCT_VERSION%
:version1 1607 [RS1]
set "V=1607"
set "D=20170116"
set "EULA=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod"
set "EULA_FIX=https://download.microsoft.com/download/C/0/3/C036B882-9F99-4BC9-A4B5-69370C4E17E9"
set "CAB=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod/Products_20170116.cab"
set "MCT=https://download.microsoft.com/download/C/F/9/CF9862F9-3D22-4811-99E7-68CE3327DAE6/MediaCreationTool.exe"
echo Version %V% %D% sélectionnée !
goto process
:version2 1703 [RS2]
set "V=1703"
set "D=20170317"
set "EULA=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod"
set "EULA_FIX=https://download.microsoft.com/download/C/0/3/C036B882-9F99-4BC9-A4B5-69370C4E17E9"
set "CAB=https://download.microsoft.com/download/9/5/4/954415FD-D9D7-4E1F-8161-41B3A4E03D5E/products_20170317.cab"
set "MCT=https://download.microsoft.com/download/1/C/4/1C41BC6B-F8AB-403B-B04E-C96ED6047488/MediaCreationTool.exe"
:: 1703 MCT est également bugué, utilisez plutôt 1607
set "MCT=https://download.microsoft.com/download/C/F/9/CF9862F9-3D22-4811-99E7-68CE3327DAE6/MediaCreationTool.exe"
echo Version %V% %D% sélectionnée !
goto process
:version3 1709 [RS3]
set "V=1709"
set "D=20180105"
set "EULA="
set "CAB=https://download.microsoft.com/download/3/2/3/323D0F94-95D2-47DE-BB83-1D4AC3331190/products_20180105.cab"
set "MCT=https://download.microsoft.com/download/A/B/E/ABEE70FE-7DE8-472A-8893-5F69947DE0B1/MediaCreationTool.exe"
echo Version %V% %D% sélectionnée !
goto process
:version4 1803 [RS4]
set "V=1803"
set "D=20180420"
set "EULA="
set "CAB=https://download.microsoft.com/download/6/2/6/626729CF-8C1C-43DF-8C9C-AD2FD56948C3/products_20180420.cab"
set "MCT=https://software-download.microsoft.com/download/pr/MediaCreationTool1803.exe"
echo Version %V% %D% sélectionnée !
goto process
:version5 1809 [RS5]
set "V=1809"
set "D=20180924"
set "EULA="
set "CAB=https://download.microsoft.com/download/6/F/B/6FB97F08-E010-48A4-A9DC-18FCA920CEB4/products_20180924.cab"
set "MCT=https://software-download.microsoft.com/download/pr/MediaCreationTool1809.exe"
echo Version %V% %D% sélectionnée !
goto process
:process
echo.
echo Notice : MCT dépend du service BITS! En cas de problèmes, exécutez le script en tant qu'administrateur..
bitsadmin.exe /reset /allusers 2>nul
net stop bits /y 2>nul
net start bits /y 2>nul
:: nettoyage - peut inclure également les fichiers temporaires, mais ce n'est pas conseillé car vous ne pouvez pas reprendre via C:$Windows.~WSSourcessetuphost
pushd "%~dp0"
del /f /q products.* 2>nul &rem rd /s/q C:$Windows.~WS 2>nul & rd /s/q C:$WINDOWS.~BT 2>nul
:: télécharger MCT
set "WEBCLIENT=[Net.ServicePointManager]::SecurityProtocol="tls12,tls11,tls";(new-object System.Net.WebClient)"
if not exist MediaCreationTool%V%.exe powershell -noprofile -c "%WEBCLIENT%.DownloadFile('%MCT%','MediaCreationTool%V%.exe');"
if not exist MediaCreationTool%V%.exe color 0c & echo Erreur! fichier MediaCreationTool%V%.exe manquant & pause & exit /b
:: télécharger CAB
if not exist products_%D%.cab powershell -noprofile -c "%WEBCLIENT%.DownloadFile('%CAB%','products_%D%.cab');"
if not exist products_%D%.cab color 0c & echo Erreur! fichier products_%D%.cab manquant & pause & exit /b
:: décompresser CAB
expand.exe -R products_%D%.cab -F:* . >nul 2>nul
if not exist products.xml color 0c & echo Erreur! fichier products_%D%.cab incorrect ou manquant & pause & exit /b
:: patch XML pour permettre la sélection d'éditions de canaux professionnels (Entreprise) et une correction cosmétique mineure
set "READ_XML=$f=[System.IO.File]::ReadAllText('products.xml')"
set "WRITE_XML=[System.IO.File]::WriteAllText('products.xml', $f)"
set "r1= $f=$f.Replace('IsRetailOnly>True<','IsRetailOnly>False<')"
set "r2=.Replace('%%ENTERPRISE','Windows 10 Enterprise')"
:: corrige les anciens liens EULA cassant MCT en 1607 et 1703
if not defined EULA (set "r3=") else set "r3=.Replace('%EULA%','%EULA_FIX%')"
powershell -c "%READ_XML%; %r1%%r2%%r3%; %WRITE_XML%;"
:: réemballer XML dans CAB
start "" /wait makecab products.xml products.cab
:: enfin, lancer MCT avec la configuration locale et les options de lancement facultatives
start "" MediaCreationTool%V%.exe /Selfhost %OPTIONS%
exit/b
:: utilitaires
::------------------------------------------------------------------------------------------------------------------------------
:choice %1:title %2:header %3:choices %4:output_variable [extrait de dialogue de cases d'option GUI par AveYo] publié sous licence MIT
setlocal &set "parameters=$title="%~1"; $header="%~2"; $choices="%~3"; $global:c="";"
set "s1=[void][System.Reflection.Assembly]::LoadWithPartialName('System.Windows.Forms');$f=New-Object System.Windows.Forms.Form"
set "s2=;$f.Text=$title; $f.Forecolor="Snow"; $f.BackColor=0xff180052; $f.StartPosition='CenterScreen'; $f.AutoSize=$true;"
set "s3=$g=New-Object System.Windows.Forms.GroupBox; $g.Location='40,10'; $g.Margin='0,0,40,0'; $g.MinimumSize="280,100";"
set "s4=$g.AutoSize=$true; $g.text=$header; $f.Controls.Add($g);"
set "s5=$i=1; foreach($l in $choices.split(',')){ $r=New-Object System.Windows.Forms.RadioButton; $r.Location='20,'+(30*$i);"
set "s6=$r.Name=$i;$r.Text=$l;$r.AutoSize=$true;$r.add_Click({$global:c=$this.Name}); $g.Controls.Add($r); $r.Checked=1; $i++};"
set "s7=$j=1;foreach($t in @('OK','Exit')){$b=New-Object System.Windows.Forms.Button;$b.Location=''+(120*($j-1)+80)+','+40*$i;"
set "s8=$b.Name="b"+$j; $b.Text=$t; $b.DialogResult=$j; if ($j -eq 1){$f.AcceptButton=$b}; $f.Controls.Add($b); $j++};"
set "s9=$f.Add_Shown({$f.Activate()}); $ret=$f.ShowDialog(); if ($ret -eq 2){$global:c=""}; write-host $global:c"
for /l %%# in (1,1,9) do call set "ps_Choice=%%ps_Choice%%%%s%%#:"="%%"
for /f "usebackq tokens=* delims=" %%# in (`powershell -noprofile -c "%parameters% %ps_Choice%"`) do set "output_var=%%#"
endlocal & set "%~4=%output_var%" & exit/b
::------------------------------------------------------------------------------------------------------------------------------
Exécutez ce fichier BAT en tant qu’administrateur. Une fenêtre d’invite de commande apparaîtra, suivie d’une autre fenêtre vous demandant quelle mise à jour de Windows 10 vous désirez télécharger. Vous aurez la possibilité de télécharger les versions finales de Redstone 1 à 5.
Une fois la version sélectionnée, l’outil de création de média sera téléchargé à l’emplacement où vous avez enregistré le fichier BAT. Vous pourrez ensuite lancer l’outil et l’utiliser afin de télécharger la version de Windows 10 que vous aurez choisie. L’outil vous permettra de mettre à jour votre installation actuelle ou de créer une clé USB amorçable.
Tous les fichiers sont téléchargés directement à partir des serveurs de Microsoft. Ce script BAT ne fait que vous aider à trouver le bon fichier et à lancer le téléchargement. Il ne fournit pas les fichiers lui-même et ne modifie pas les fichiers mis à disposition par Microsoft.